main

.pio/libdeps/esp32-s3-devkitc-1/RTClib/examples/DS3231_alarm/DS3231_alarm.ino

@@ -0,0 +1,122 @@
+/* Example implementation of an alarm using DS3231
+ *
+ * VCC and GND of RTC should be connected to some power source
+ * SDA, SCL of RTC should be connected to SDA, SCL of arduino
+ * SQW should be connected to CLOCK_INTERRUPT_PIN
+ * CLOCK_INTERRUPT_PIN needs to work with interrupts
+ */
+
+#include <RTClib.h>
+// #include <Wire.h>
+
+RTC_DS3231 rtc;
+
+// the pin that is connected to SQW
+#define CLOCK_INTERRUPT_PIN 2
+
+void setup() {
+    Serial.begin(9600);
+
+    // initializing the rtc
+    if(!rtc.begin()) {
+        Serial.println("Couldn't find RTC!");
+        Serial.flush();
+        while (1) delay(10);
+    }
+
+    if(rtc.lostPower()) {
+        // this will adjust to the date and time at compilation
+        rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));
+    }
+
+    //we don't need the 32K Pin, so disable it
+    rtc.disable32K();
+
+    // Making it so, that the alarm will trigger an interrupt
+    pinMode(CLOCK_INTERRUPT_PIN, INPUT_PULLUP);
+    attachInterrupt(digitalPinToInterrupt(CLOCK_INTERRUPT_PIN), onAlarm, FALLING);
+
+    // set alarm 1, 2 flag to false (so alarm 1, 2 didn't happen so far)
+    // if not done, this easily leads to problems, as both register aren't reset on reboot/recompile
+    rtc.clearAlarm(1);
+    rtc.clearAlarm(2);
+
+    // stop oscillating signals at SQW Pin
+    // otherwise setAlarm1 will fail
+    rtc.writeSqwPinMode(DS3231_OFF);
+
+    // turn off alarm 2 (in case it isn't off already)
+    // again, this isn't done at reboot, so a previously set alarm could easily go overlooked
+    rtc.disableAlarm(2);
+
+    // schedule an alarm 10 seconds in the future
+    if(!rtc.setAlarm1(
+            rtc.now() + TimeSpan(10),
+            DS3231_A1_Second // this mode triggers the alarm when the seconds match. See Doxygen for other options
+    )) {
+        Serial.println("Error, alarm wasn't set!");
+    }else {
+        Serial.println("Alarm will happen in 10 seconds!");
+    }
+}
+
+void loop() {
+    // print current time
+    char date[10] = "hh:mm:ss";
+    rtc.now().toString(date);
+    Serial.print(date);
+
+    // the stored alarm value + mode
+    DateTime alarm1 = rtc.getAlarm1();
+    Ds3231Alarm1Mode alarm1mode = rtc.getAlarm1Mode();
+    char alarm1Date[12] = "DD hh:mm:ss";
+    alarm1.toString(alarm1Date);
+    Serial.print(" [Alarm1: ");
+    Serial.print(alarm1Date);
+    Serial.print(", Mode: ");
+    switch (alarm1mode) {
+      case DS3231_A1_PerSecond: Serial.print("PerSecond"); break;
+      case DS3231_A1_Second: Serial.print("Second"); break;
+      case DS3231_A1_Minute: Serial.print("Minute"); break;
+      case DS3231_A1_Hour: Serial.print("Hour"); break;
+      case DS3231_A1_Date: Serial.print("Date"); break;
+      case DS3231_A1_Day: Serial.print("Day"); break;
+    }
+
+    // the value at SQW-Pin (because of pullup 1 means no alarm)
+    Serial.print("] SQW: ");
+    Serial.print(digitalRead(CLOCK_INTERRUPT_PIN));
+
+    // whether a alarm fired
+    Serial.print(" Fired: ");
+    Serial.print(rtc.alarmFired(1));
+
+    // Serial.print(" Alarm2: ");
+    // Serial.println(rtc.alarmFired(2));
+    // control register values (see https://datasheets.maximintegrated.com/en/ds/DS3231.pdf page 13)
+    // Serial.print(" Control: 0b");
+    // Serial.println(read_i2c_register(DS3231_ADDRESS, DS3231_CONTROL), BIN);
+
+    // resetting SQW and alarm 1 flag
+    // using setAlarm1, the next alarm could now be configurated
+    if (rtc.alarmFired(1)) {
+        rtc.clearAlarm(1);
+        Serial.print(" - Alarm cleared");
+    }
+    Serial.println();
+
+    delay(2000);
+}
+
+void onAlarm() {
+    Serial.println("Alarm occured!");
+}
+
+/*static uint8_t read_i2c_register(uint8_t addr, uint8_t reg) {
+    Wire.beginTransmission(addr);
+    Wire.write((byte)reg);
+    Wire.endTransmission();
+
+    Wire.requestFrom(addr, (byte)1);
+    return Wire.read();
+}*/